PARTNO		31XXXX ;
		NAME            U123 ;
		DATE            January 28, 1991 ;
		REV             1 ;
		DESIGNER        Dave Haynie ;
		COMPANY         Commodore ;
		ASSEMBLY        A3000+ ;
		Location        U123 ;

/************************************************************************/
/*									*/
/*  A3000+	DSP3210 Bus Arbiter 					*/
/*									*/
/************************************************************************/
/*  Allowable Target Device Types: 16R4-10 				*/
/************************************************************************/
/*  Clock:		dspCLK (50MHz)					*/
/************************************************************************/
/*  Free Pins:		NONE						*/
/************************************************************************/
/*  HISTORY								*/
/*	DBH Jan 31:	Completely new.					*/
/************************************************************************/

/** Inputs **/

PIN 2		= !XFER32	;	/* A 32 bit DSP transfer happened */
PIN 3		= !dspBR	;	/* DSP bus request */
PIN 4		= !dspBGACK	;	/* DSP bus grant acknowledge */
PIN 5		= !XBG		;	/* Arbitrated bus grant */
PIN 6		= !SBR		;	/* SCSI bus request */
PIN 7		= !AS		;	/* 030 Address Strobe */
PIN 9		= !STERM	;	/* 030 synchronous termination */
PIN 19		= !preBERR	;	/* Unsynced DSP Bus Error */

/**  Outputs  **/

PIN 14		= !dspSRDY	;	/* DSP transfer acknowledge */
PIN 15		= !dspBG	;	/* DSP bus grant */
PIN 16		= !SBG		;	/* SCSI bus grant */
PIN 17		= !dspBERR	;	/* DSP bus error */
PIN 18		= !BGACK	;	/* 030 bus grant acknowledge */

/**  Declarations and Intermediate Variable Definitions  **/

/**  Logic Equations  **/

/* Here the 32 bit transfer acknowledges are synched up to make a proper
   DSP acknowledge */

dspSRDY.D	= XFER32 & dspBGACK
		# STERM  & dspBGACK;

/* Sync up the bus error signal */

dspBERR.D	= preBERR;

/* Some bus arbitration stuff.  The '030 compatible bus arbitration lines in
   Buster, XBR and XBG, are shared between SCSI and DSP, with priority given
   to DSP.  */

SBG.D		= SBR & XBG & !dspBR & !dspBGACK
		# SBR & SBG;

dspBG.D		= dspBR & XBG & !SBG & !AS
		# dspBR & dspBG;

/* The 68030 bus grant acknowledge is driven here for the DSP. */

BGACK		= dspBR & XBG & !SBG & !AS
		# dspBR & dspBG;
BGACK.OE	= dspBR;