PARTNO	  390289-01 ;
		NAME	  U304;
		DATE	  Dec 22, 1987 ;
		REV	  9 ;
		DESIGNER  Welland/Haynie ;
		COMPANY   Commodore ;
		ASSEMBLY  312828 ;
		LOCATION  U304;

/******************************************************************/
/*								  */
/*  68020 MMU	ROM and AUTOconfig chip selects, Onboard	  */
/*		generation and HAAZ generation (A24-A28 == 0)	  */
/*								  */
/******************************************************************/
/*  Allowable Target Device Types: 20L8A (390325-01)		  */
/******************************************************************/
/*  Free Pins: NONE 						  */
/******************************************************************/
/*  HISTORY							  */
/*	DBH Dec 22:	Reversed NORAM polarity 		  */
/*	DBH Dec 22:	Adjusted pinout as per R4.0 spec	  */
/*	DBH Dec 22:	Added FULLRESET logic, part of 68K mode	  */
/******************************************************************/

/**  Inputs  **/

PIN 1	     = !AS	 ;	/* Address strobe */
PIN 2	     = PRW	 ;	/* Processor Read/Write */
PIN 3	     = PHANLOW	 ;	/* ROM Phantom Low enable */
PIN 4	     = PHANHIGH	 ;	/* ROM Phantom High enable */
PIN 21	     = RAMCONF	 ;	/* The board is fully configed */
PIN 5	     = ROMCONF	 ;	/* The rom is configed */
PIN 6	     = !NORAM	 ;	/* This board has no ram onboard */
PIN [9..11]  = [A23..21] ;	/* Address line 27-21  */
PIN 13	     = A20	 ;	/* Address line 20 */
PIN 14	     = A19	 ;	/* Address line 19 */
PIN 23	     = A18	 ;	/* Address line 18 */
PIN 8	     = A17	 ;	/* Address line 17 */
PIN 7	     = A16	 ;	/* Address line 16 */
PIN 19	     = !HALT	 ;	/* CPU /Halt Line, to indicate full reset */
PIN 20	     = !RESET	 ;	/* CPU /Reset Line, to indicate full reset */

/**  Outputs  **/

PIN 15	     = !CSAUTO	 ;	/* Auto config chip select */
PIN 16	     = !CSROM	 ;	/* Rom chip select */
PIN 17	     = !ONBOARD  ;	/* Addressed location is on board */
PIN 22	     = !FULLRESET;	/* Indicates full system reset, like C-A-A */

/**  Used Internally **/

PIN 18	     = !DUMMY	 ;	/* Dummy output to latch CSAUTO */


/** Declarations and Intermediate Variable Definitions **/

field addr = [A23..16];

readcycle  = (PRW & AS);

autocon  = addr:[e80000..e8ffff];	/* auto config space */
hirom	 = addr:[f80000..f8ffff];	/* high memory rom space */
lowrom	 = addr:[000000..00ffff];	/* low memory rom space */
icsrom	 = ((hirom & !PHANHIGH) # (lowrom & !PHANLOW)) & readcycle;
icsauto  = autocon & AS & ((!RAMCONF & !NORAM) # (!ROMCONF & NORAM));

/**  Logic Equations  **/

CSROM	 = icsrom;
CSAUTO	 = icsauto
	 # DUMMY & AS;
DUMMY	 = icsauto
	 # DUMMY & AS;
ONBOARD  = icsrom # icsauto
	 # ONBOARD & AS;

FULLRESET = HALT & RESET;