PARTNO		U690 ;
		NAME		U690 ;
		DATE		October 26, 1992 ;
		REV		0 ;
		DESIGNER	Haynie ;
		COMPANY 	Commodore ;
		ASSEMBLY	Nyx ;
		LOCATION	West Chester ;
		DEVICE		g22v10 ;

/************************************************************************/
/*									*/
/* 	Nyx	Bus Address Mapper					*/
/*									*/
/*	This device generates the address mapping for the Zorro bus.    */
/*	It also generates Zorro II read data latch and Zorro III DMA 	*/
/* 	address latch controls.						*/
/*									*/
/************************************************************************/
/*  Allowable Target Device Types: 22V10-10	 			*/
/************************************************************************/
/*  Clock:		NONE						*/
/************************************************************************/
/*  Free Pins:		NONE						*/
/************************************************************************/
/*  HISTORY								*/
/*	DBH Oct 26:	Descended from A3000+ U690, Rev 3.		*/
/************************************************************************/

/** INPUTS: **/

PIN [1..11]	= [A20..30]	;	/* Bus address */
PIN 13		=  A31		;
PIN 14		= !FCS		;	/* Zorro II cycle strobe */
PIN 15		= !CCS		;	/* 68000 compatible cycle strobe */
PIN 21		=  C7M		;	/* 68000 basis clock */
PIN 22		=  A18		;	/* More bus address */
PIN 23		=  A19		;

/** OUTPUTS: **/

PIN 16		=  ABLT		;	/* DMA address latch. */
PIN 17		= !ADDRZ3	;	/* Zorro III space */
PIN 18		= !MEMZ2	;	/* Zorro II memory space */
PIN 19		= !IOZ2		;	/* Zorro II I/O space */
PIN 20		=  READLT	;	/* When to latch data? */

/** INTERNAL TERMS: */

field addr	= [A31..18];		/* Full system address */

field addr68k	= [A23..18];		/* 68000 address subset */

/* The 68000 space doesn't always get qualified with a full 32 bit address.
   Thus, it must be qualified either by address or by the presence of the
   proper strobe. */

cyc68k		= addr:[00ffffff..00000000] 
		# CCS;

/** OUTPUT TERMS: **/

/* The Zorro III space occupies the bottom 1/2 of memory, except for the
   first 256 megabytes.  The top chunk for secondary autoconfig address
   is also Zorro III space. */

ADDRZ3		= addr:[7fffffff..10000000]
		# addr:[ff00ffff..ff000000];

/* The Zorro II I/O space is in the normal 68000 $e80000..$efffff range,
   just like on the A2000, plus an additional 1.5 megabyte chunk right above
   memory space (a reasonable place to put things like Bridge Cards, if 
   they ever fix up their decoding...). */

IOZ2		= addr68k:[00efffff..00e80000] & cyc68k
		# addr68k:[00b7ffff..00a00000] & cyc68k;

/* The Zorro II memory space is in the normal 68000 $200000..$9fffff range, 
   just like on the A2000.  The magic cookie space shows up here for
   private Commodore uses, and can only be seen by the local bus. */

MEMZ2		= addr68k:[009fffff..00200000] & cyc68k
		#    addr:[00f7ffff..00f00000];

/* The address latch output is based on FCS. */

ABLT		= FCS;

/* The read latch needs to kick in near the end of the 68000 cycle.  Latching
   is on the falling edge of C7M. */

READLT		= !C7M & CCS;